وب سايت رسمي شركت راهكار نوين

Display the total free space available on drive C:. Because Visual Basic doesn't have good support for the 64-bit integers needed for modern hard drive's free spaces, the workaround described on this page is needed to display the values properly. This example runs when the user click button Command1, so to use this example, you need to place a command button named Command1 on a form window. 
' Declarations and such needed for the example: 
' (Copy them to the (declarations) section of a module.)

Public Type ULARGE_INTEGER

    LowPart As Long

    HighPart As Long

End Type

Public Declare Function GetDiskFreeSpaceEx Lib "kernel32.dll" Alias "GetDiskFreeSpaceExA" (ByVal _

    lpDirectoryName As String, lpFreeBytesAvailableToCaller As ULARGE_INTEGER, _

    lpTotalNumberOfBytes As ULARGE_INTEGER, lpTotalNumberOfFreeBytes As ULARGE_INTEGER) As Long

Public Declare Sub CopyMemory Lib "kernel32.dll" Alias "RtlMoveMemory" (Destination As Any, Source _

    As Any, ByVal Length As Long)

 

' *** Place the following code inside the form window. ***

 

Private Sub Command1_Click()

    Dim userbytes As ULARGE_INTEGER   ' bytes free to user

    Dim totalbytes As ULARGE_INTEGER  ' total bytes on disk

    Dim freebytes As ULARGE_INTEGER   ' free bytes on disk

    Dim tempval As Currency           ' display buffer for 64-bit values

    Dim retval As Long                ' generic return value

    

    ' Get information about the C: drive.

    retval = GetDiskFreeSpaceEx("C:\", userbytes, totalbytes, freebytes)

    ' Copy freebytes into the Currency data type.

    CopyMemory tempval, freebytes, 8

    ' Multiply by 10,000 to move Visual Basic's decimal point to the end of the actual number.

    tempval = tempval * 10000

    ' Display the amount of free space on C:.

    Debug.Print "Free Space on the C: drive:"; tempval; "bytes"

End Sub
 

' Determine what type of drive D: is

Dim drivetype As Long  ' receives the drive type

 

drivetype = GetDriveType("d:\")  ' determine which kind of drive this is

If drivetype = 1 Then Debug.Print "Drive D:\ does not exist."

If drivetype = DRIVE_REMOVABLE Then Print "Drive D:\ is a removable-disk drive."

If drivetype = DRIVE_FIXED Then Print "Drive D:\ is a hard drive."

If drivetype = DRIVE_CDROM Then Print "Drive D:\ is a CD-ROM drive."

' etc.
 

' Tell the user which drives exist on the computer.  Note how this example

' only checks up to drive D:, but it does establish the necessary pattern to use in general.

Dim driveflags As Long  ' receives the flags identifying valid drives

 

' Get the valid logical drives on the computer.

driveflags = GetLogicalDrives()

' Test the returned value to see if drives A: through D: exist.

If (driveflags And 1) = 1 Then Debug.Print "Drive A: exists."

If (driveflags And 2) = 2 Then Debug.Print "Drive B: exists."

If (driveflags And 4) = 4 Then Debug.Print "Drive C: exists."

If (driveflags And 8) = 8 Then Debug.Print "Drive D: exists."

' And so on....
 

' List the names of all the root directories.  Since each entry in the string takes

' four characters (three for the name and one for the null), we can "count by fours" going

' through the string until we reach the end.  This frees us from worrying about nulls.

Dim drivenames As String  ' receives list of root names

Dim thisdrive As String  ' buffer for one extracted root directory name

Dim c As Long  ' counter variable

Dim slength As Long  ' receives length of returned string

' Make enough room in the buffer to receive the drive names.

drivenames = Space(255)  ' more than enough room

' Get the root directory names of all logical drives.

slength = GetLogicalDriveStrings(255, drivenames)  ' drivenames now holds the list

' Count by fours to extract the names of each drive.

For c = 1 To slength Step 4  ' loop with an increment of 4

  thisdrive = Mid(drivenames, c, 3)  ' extract a 3-character string X:\ (X is the drive letter)

  Debug.Print thisdrive  ' display the drive name

Next c